Aminet 21/Aminet 21 (1997)(GTI - Schatztruhe)[!][Oct 1997].iso/Aminet/util/misc/EuraTools.lha/EuraTools/Install

Text File | 1997-08-08 | 11.5 KB | 405 lines

;**********************************************************
;*                                                        *
;*           EuraTools HD Installer Script                *
;*                                                        *
;**********************************************************
;*
;*      $VER: Install-EuraTools 4.3 (8.8.97)
;*      (C) 1997 Richard Körber -- All Rights Reserved
;*
;**********************************************************


;********* MESSAGES ***************************************

(set MStartup
  (cat  "\nWillkommen zur\n\n"
        "EuraTools Installation\n\n\n"
        "EuraTools ist Shareware. Sie dürfen die "
        "Programme einen Monat lang testen. Danach "
        "müssen Sie sich registrieren lassen oder "
        "das gesamte Paket löschen.\n\n"
        "Lesen Sie bitte unbedingt VOR dem ersten "
        "Start die Anleitung!"
  )
)

(set MNeedMUI
  (cat  "\n** ACHTUNG **\n\n"
        "EuraTools benötigt MUI V3!\n\n"
        "Sie müssen MUI installieren, um EuraTools "
        "verwenden zu können. MUI finden Sie auf "
        "jeder gut sortierten Public Domain-CD-ROM "
        "oder unter http://www.sasg.com ."
  )
)

(set MNewKey
  (cat  "\nAb dieser Release verwendet EuraTools "
        "ein neues Keyfile.\n\n"
        "Bitte installieren Sie es, falls noch nicht geschehen!"
  )
)

(set PDestDir
  (cat  "Wohin soll EuraTools installiert werden?\n"
        "Eine Schublade wird dort automatisch erzeugt."
  )
)

(set HDestDir
  (cat  "Wählen Sie ein Zielverzeichnis aus, z. B. "
        "'Work:'. Sie brauchen kein eigenes Verzeichnis "
        "für EuraTools anlegen, da es automatisch erzeugt wird!\n\n"
        "Wählen Sie nach Möglichkeit nicht das Verzeichnis, in dem "
        "Sie eine alte Version von EuraConfig gespeichert haben. "
        "Um dieses können Sie sich später kümmern."
  )
)

(set PAsk020
        "Welche Version von EuraTools möchten Sie installieren?"
)

(set HAsk020
  (cat  "Es gibt eine Version für alle Prozessoren (68000-Version) "
        "und eine Version, die spezielle Befehle ab dem 68020 ausnutzt.\n\n"
        "Wenn Sie einen 68000- oder 68010-Prozessor benutzen, sollten "
        "Sie unbedingt die 68000-Version installieren, da die 68020-Version "
        "dort nicht funktionieren wird.\n\n"
        "Wenn Sie einen 68020, 68030, 68040 oder 68060 benutzen, können "
        "Sie beide Versionen installieren. Die 68020-Version ist jedoch "
        "vorzuziehen, da sie kürzer ist und schneller arbeitet.\n\n"
        "Im Zweifelsfall verwenden Sie einfach die voreingestellte Wahl."
  )
)

(set CCPU000 "68000-Version")
(set CCPU020 "68020-Version")

(set PProgCopy     "Welche Programme sollen installiert werden?")
(set HProgCopy
  (cat  "Welche Programme aus dem Paket sollen installiert werden?\n\n"
        "EuraConfig ist das Konfigurationsprogramm für die TK-Anlage.\n\n"
        "EuraCall ist eine Gebührenauswertung, die jedoch das Gebührenkit "
        "oder PassCall benötigt.\n\n"
        "Register ist ein Registrationsprogramm, daß Sie nur benötigen, "
        "wenn Sie noch nicht registriert sind."
  )
)

(set PDocCopy      "Welche Dokumentationen sollen installiert werden?")
(set HDocCopy
  (cat  "Welche Dokumentationen sollen installiert werden (falls vorhanden) ?\n\n"
        "EuraTools.guide ist die eigentliche Anleitung. Sie wird auch für die "
        "Online-Hilfe benötigt.\n\n"
        "History.guide ist eine Textdatei, die die Änderungen in den letzten "
        "Versionen auflistet."
  )
)

(set PAssign       "Füge einen Assign in die User-Startup ein.")
(set HAssign
  (cat  "In die Datei User-Startup wird ein Assign eingefügt, der bei "
        "jedem Systemstart automatisch ausgeführt wird. Der Assign "
        "erleichtert die Konfiguration und Arbeitsweise von EuraTools, "
        "er ist jedoch nicht wirklich erforderlich.\n\n"
        "Eingefügt wird:\n\n"
        "Assign EuraTools: <Zielverzeichnis>"
  )
)

(set PARexxCopy    "Möchten Sie die ARexx-Scripte installieren?")
(set HARexxCopy
  (cat  "Dies sind nützliche ARexx-Scripte, die Ihnen die Arbeit "
        "mit der Anlage erleichtern sollen. Sie dienen auch als "
        "Beispiel für eigene Scripts.\n\n"
        "Die Beschreibung zu den Scripten finden Sie in der Anleitung "
        "oder in den Scripten selbst.\n\n"
        "Im Experten-Modus können Sie das Zielverzeichnis für die "
        "Scripts auswählen. Ansonsten werden sie in einem Unterverzeichnis "
        "zu den EuraTools-Programmen abgelegt."
  )
)
(set PARexxCopying "Kopiere die ARexx-Scripte...")
(set PARexxDir     "Wohin sollen die ARexx-Scripte kopiert werden?")
(set HARexxDir
  (cat  "Dies ist das Zielverzeichnis für die ARexx-Scripts. Ich "
        "empfehle, sie in den vorgeschlagenen Pfad zu installieren. "
        "Ansonsten sollte der Übersichtlichkeit halber ein Unterverzeichnis "
        "angelegt werden."
  )
)

(set PMuiCopying   "Kopiere die MUI-MCCs...")
(set PMuiDir       "Wohin sollen die MUI-MCCs kopiert werden?")
(set HMuiDir
  (cat  "Dies ist das Zielverzeichnis für die MUI-MCCs von EuraTools.\n\n"
        "Sie können in dem vorgeschlagenen Pfad hineinkopiert werden, "
        "das erfordert allerdings, daß beim Programmstart das EuraTools-Verzeichnis "
        "das aktuelle Verzeichnis ist.\n\n"
        "Eine weitere Möglichkeit ist das Verzeichnis 'MUI:libs/mui/'. Dies verstößt "
        "zwar gegen MUI-Richtlinien, aber das Programm kann dann aus jedem Verzeichnis "
        "heraus gestartet werden."
  )
)

(set PPubMuiCopying  "Kopiere die öffentlichen MUI-MCCs...")
(set HPubMuiCopying
  (cat  "EuraConfig verwendet die lamp.mcc von Maik Schreiber.\n\n"
        "Die dazugehörigen Dateien werden jetzt in das MUI-Verzeichnis installiert. "
        "Updates finden Sie stets unter 'http://home.pages.de/~bZ/projekte/mcc_lamp/' ."
  )
)

(set PPatch        "Patche auf 68020-Version.")


(set PPCChoice     "Wohin soll PassCall kopiert werden?")
(set HPCChoice
  (cat  "PassCall ermöglicht Ihnen eine Gebührenauswertung mit EuraCall "
        "über den Druckerport. Das Gebührenkit wird dazu nicht benötigt.\n\n"
        "Wenn Sie ein Gebührenkit besitzen, brauchen Sie PassCall nicht "
        "zu installieren.\n\n"
        "PassCall muß zum ordnungsgemäßen Betrieb stets im Hintergrund laufen. "
        "Es kann daher Sinnvoll sein, PassCall direkt in die WBStartup-Schublade "
        "Ihrer Workbench zu installieren. Dies können Sie natürlich auch jederzeit "
        "nachholen oder rückgängig machen."
  )
)
(set CPCOwnDir     "Anderes Verzeichnis")
(set CPCNot        "Nicht installieren")
(set PPCDestDir    "Wählen Sie das Verzeichnis für PassCall...")
(set HPCDestDir
  (cat  "Hier wählen Sie aus, in welches Verzeichnis PassCall installiert "
        "werden soll. Empfehlenswert ist das Verzeichnis von EuraTools oder "
        "das WBStartup-Verzeichnis Ihrer Workbench."
  )
)
(set PPCCopy       "Kopiere PassCall...")
(set HPCCopy       "PassCall wird jetzt in das von Ihnen angegebene Verzeichnis kopiert.")
(set MPassCall
  (cat  "HINWEIS\n\n"
        "PassCall ist auf die interne serielle Schnittstelle und dem Assign "
        "EuraTools: als Pfad voreingestellt.\n\n"
        "Bitte korrigieren Sie diese Voreinstellungen vor dem ersten Start "
        "von PassCall, wenn erforderlich!"
  )
)

;********* FILES ******************************************

(set FEuraCfg     "EuraConfig")
(set FEuraCall    "EuraCall")
(set FPassCall    "PassCall")
(set FRegister    "Register")
(set FEuraCfg000  "EuraConfig_000.pch")
(set FEuraCall000 "EuraCall_000.pch")
(set FPatch       "spatch")
(set FEuraDoc     "EuraTools.guide")
(set FEuraHist    "History.guide")
(set FARexxDir    "arexx/")
(set FMuiDir      "mui/")
(set FPubMuiDir   "MUI:libs/mui/")
(set FWBStartup   "SYS:WBStartup/")


;********* INSTALLER SCRIPT *******************************

;------ Greetings to the user -----------------------------
(message MStartup)

;------ Is MUI available? ---------------------------------
(if (<> (exists "libs:muimaster.library") 1)
  (message MNeedMUI)
)

;------ Is an old keyfile available? ----------------------
(if (= (exists "S:EuraConfig.keyfile") 1)
  (message MNewKey)
)

;------ Ask for the destination drawer and create it ------
(if (= (exists "EuraTools:" (noreq)) 0)
  (
    (set DestDir
      (askdir
        (prompt  PDestDir)
        (help    HDestDir)
        (default "Work:")
      )
    )
    (set DestDir
      (tackon DestDir "EuraTools")
    )
    (makedir
      (DestDir)
      (infos)
    )
    (startup   "EuraTools"
      (command ("Assign EuraTools: \"%s\"" DestDir))
      (prompt  PAssign)
      (help    HAssign)
    )
  )
  (set DestDir "EuraTools:")
)
(set @default-dest (DestDir))

;------ Find out the CPU ----------------------------------
(set UsedCpu (+ (database "cpu")))
(if (< UsedCpu 68020)
  (set UsedCpu 0)
  (set UsedCpu 1)
)
(if (= @user-level 2)
  (set UsedCpu
    (askchoice
      (prompt PAsk020)
      (help   HAsk020)
      (choices CCPU000 CCPU020)
      (default UsedCpu)
    )
  )
)

;------ Install the Programs ------------------------------
(copyfiles
  (prompt  PProgCopy)
  (help    HProgCopy)
  (source  "")
  (choices FEuraCfg FEuraCall FRegister)
  (dest    DestDir)
  (infos)
  (noposition)
  (confirm)
)

(if (= UsedCpu 0)
  (
    (set Sourcefile (tackon DestDir FEuraCfg))
    (if (= (exists Sourcefile) 1)
      (
        (set Cmd (cat FPatch " -o" Sourcefile " -p" FEuraCfg000 " " Sourcefile))
        (run Cmd (prompt PPatch))
      )
    )
    (set Sourcefile (tackon DestDir FEuraCall))
    (if (= (exists Sourcefile) 1)
      (
        (set Cmd (cat FPatch " -o" Sourcefile " -p" FEuraCall000 " " Sourcefile))
        (run Cmd (prompt PPatch))
      )
    )
  )
)

(if (= @user-level 0)
  (set PCChoice 0)              ; Novice always installs to EuraTools:
  (set PCChoice
    (askchoice
      (prompt PPCChoice)
      (help   HPCChoice)
      (choices DestDir FWBStartup CPCOwnDir CPCNot)
      (default 1)
    )
  )
)
(if (<> PCChoice 3)
  (
    (if (= PCChoice 0) (set PCDestDir DestDir))
    (if (= PCChoice 1) (set PCDestDir FWBStartup))
    (if (= PCChoice 2) (set PCDestDir (askdir (prompt PPCDestDir) (help HPCDestDir) (default DestDir))))
    (copyfiles
      (prompt  PPCCopy)
      (help    HPCCopy)
      (source  FPassCall)
      (dest    PCDestDir)
      (infos)
      (noposition)
    )
    (message MPassCall)
  )
)

;------ Install the Documentations ------------------------
(copyfiles
  (prompt  PDocCopy)
  (help    HDocCopy)
  (source  "")
  (choices FEuraDoc FEuraHist)
  (dest    DestDir)
  (infos)
  (noposition)
  (confirm)
)

;------ Install the own MUI mcc ---------------------------
(set MuiDir
  (tackon DestDir FMuiDir)
)
(makedir
  (MuiDir)
)
(if (= @user-level 2)
  (set MuiDir
    (askdir
      (prompt  PMuiDir)
      (help    HMuiDir)
      (default MuiDir)
    )
  )
)
(copyfiles
  (prompt  PMuiCopying)
  (source  FMuiDir)
  (dest    MuiDir)
  (pattern "S7981_#?")
)

;------ Install the public MUI mcc -----------------------
(copyfiles
  (prompt  PPubMuiCopying)
  (source  FMuiDir)
  (dest    FPubMuiDir)
  (pattern "~(S7981_#?)")
  (help    HPubMuiCopying)
  (confirm)
)

;------ Install the ARexx Scripts -------------------------
(if
  (askbool
    (prompt PARexxCopy)
    (help   HARexxCopy)
    (default 1)
  )
(
  (set ARexxDir
    (tackon DestDir FARexxDir)
  )
  (makedir
    (ARexxDir)
  )
  (if (= @user-level 2)
    (set ARexxDir
      (askdir
        (prompt  PARexxDir)
        (help    HARexxDir)
        (default ARexxDir)
      )
    )
  )
  (copyfiles
    (prompt  PARexxCopying)
    (source  FARexxDir)
    (dest    ARexxDir)
    (all)
  )
))

(exit)

;********* DONE *******************************************